Working with Permutations
Creating a Permutation
The Action of a Permutation
Other Operations on Permutations
To create a permutation in Maple, you must specify either an explicit list of the images of the integers in the range 1..n, or the disjoint cycle structure of the permutation. In the first case, you use a list L of the form [a__1, a__2, ..., a__n], where a__i is the image of i under the permutation.
p := Perm( [2, 3, 1] );
To create a permutation by specifying its disjoint cycle structure, use nested lists in which each sublist represents the corresponding cycle.
p := Perm( [[1,3],[2,5,4]] );
In this earlier example, the sublist [1,3] represents the cycle (transposition) that interchanges the points 1 and 3, and the sublist [2,5,4] represents the cycle that takes 2 to 5, 5 to 4 and 4 to 2.
Note that permutations are displayed in disjoint cycle notation.
Permutations have type Perm.
type( p, 'Perm' );
Many of the commands available for computing with permutations reside in the GroupTheory package, and the following command can be used to access them.
with( GroupTheory ):
To apply a permutation p to a point i, you use the "indexed" notation p[i]. For example,
p := Perm( [[1,2],[3,4,5]] );
p[ 3 ];
Note: Despite the notation, permutations act on the 'right'. This is important to understand when multiplying (or composing) permutations.
You can also use the PermApply command to compute the image of a point, or to map a permutation onto a set or list of points.
PermApply( p, 3 );
map2( PermApply, p, [ 1, 3, 5 ] );
The set of points that are actually displaced by a permutation is called the "support" of the permutation. To compute the set of moved points, use the PermSupport command.
p := Perm( [[1, 3], [4,6,7]] );
PermSupport( p );
The largest point moved by a permutation is called the "degree" of the permutation, you can compute it by using the PermDegree command.
PermDegree( p );
The PermFixed command returns the set of those points less or equal to the degree of a permutation that are fixed by it.
PermFixed( p );
The noncommutative multiplication operator . is used to multiply (or compose) two permutations.
a := Perm( [[1,2]] ); b := Perm( [[2,3,4]] );
a . b;
b . a;
Observe that a·b and b·a are different permutations; that is, multiplication of permutation is, in general, 'not' commutative.
You can compute a power an, for an integer n, of a permutation a, by using the `^` operator.
In particular, you can compute the inverse of a permutation as a power with −1.
You can also compute the inverse of a permutation by using the PermInverse command.
PermInverse( b );
Note that computing powers of a permutation is efficient for large powers.
Alternatively, you can use the PermPower command.
PermPower( a, 5 );
The smallest positive integer n for which an is the identity permutation is called the "order" of the permutation a. The PermOrder command computes the order of a permutation.
PermOrder( b );
PermOrder( a );
To compute the conjugate ab of a permutation a by a permutation b, you can use either exponential notation, or the PermConjugate command.
PermConjugate( a, b );
The commutator 1a·1b·a·b of two permutations a and b is computed by the PermCommutator command.
PermCommutator( a, b );
Every permutation p can be written as a product of transpositions. There are infinitely many such products for any given permutation, but the number of transpositions in such a product is either always even or always odd. The "parity" of p is defined to be 1 if p can be written as a product of an even number of transpositions, and is defined to be −1 otherwise. This defines a homomorphism from the symmetric group Sn to the multiplicative group −1,1. The PermParity command computes this homomorphism.
PermParity( a );
PermParity( b );
Every permutation can be written, in an essentially unique way, as a product of disjoint cycles. The multi-set of lengths of these cycles is called the "cycle type" of the permutation, and the PermCycleType command computes the cycle type as a list of the form c1,c2,..,ck, where the lengths of the cycles in a disjoint cycle decomposition of the permutation are listed in non-decreasing order. Thus, a cycle type of 2,2,3,5,5 indicates a permutation that is a product of two transpositions, one 3-cycle and two 5-cycles.
PermCycleType( b );
PermCycleType( Perm([[1,2],[3,4,5],[6,7,8],[9,10],[11,12,13,14,15]] ) );
The Working with Permutations tutorial was introduced in Maple 2015.
For more information on Maple 2015 changes, see Updates in Maple 2015.
Download Help Document