Tensors - a complete guide

All Products Maple MapleSim

Home : Support : Online Help : Physics : Tensors - a complete guide

A Complete Guide for performing Tensors computations using Physics

The Physics package, developed by Maplesoft, is an integral part of the Maple system. The package includes commands for Classical and Quantum Mechanics, Classical Field Theory and General Relativity. It also includes 5 subpackages: Vectors, StandardModel, FeynmanIntegral, and Tetrads and ThreePlusOne which are related to General Relativity.

Section I of this guide includes the information needed to compute with tensors in Classical and Quantum Mechanics, Electrodynamics and Special Relativity, using the Physics package. This section is also relevant for computations in General Relativity. Section II is completely devoted to working with tensors in curved spacetimes. Section III is about transformations of coordinates.

To transform this page into an active computational worksheet that enables you to reproduce its contents, click the corresponding icon on the toolbar.

For an alphabetical list of the Physics commands with one-line descriptions and links to the corresponding help pages see Physics: Brief description of each command.

I. Spacetime and tensors in Physics

1	Default metric, signature and coordinates

a	Systems of coordinates

1	Tensors, their definition, symmetries and operations

a	Defining a tensor by passing the tensor itself

b	Defining a tensor by passing a tensorial equation

c	Automatic formatting of repeated tensor indices and handling of their collisions in products

d	Tensor symmetries

e	Substituting tensors and tensor indices

f	Simplifying tensorial expressions

g	Sum over repeated indices

h	Visualizing tensor components - Library:-TensorComponents and TensorArray

i	Modifying tensor components - Library:-RedefineTensorComponent

j	Using CompactDisplay to enhance the display of tensorial expressions involving tensor functions and derivatives

1	The LeviCivita tensor and KroneckerDelta

2	The 3D space metric and decomposing 4D tensors into their 3D space part and the rest

3	Total differentials, the d_[mu] and dAlembertian operators

4	Tensorial differential operators in algebraic expressions

5	Inert tensors

6	Functional differentiation of tensorial expressions with respect to tensor functions

7	The Pauli matrices and the spacetime Psigma[mu] 4-vector

8	The Dirac matrices and the spacetime Dgamma[mu] 4-vector

9	Quantum not-commutative operators using tensor notation

II. Curved spacetimes

10	Loading metrics from the database of solutions to Einstein's equations

11	Setting the spacetime metric indicating the line element or a Matrix

12	Covariant differentiation: the D_[mu] operator and the Christoffel symbols

13	The LeviCivita tensor in curved spacetimes and the determinant of the metric

14	The Einstein, Ricci, Riemann and Weyl tensors of General Relativity

15	The EnergyMomentum tensor

16	Killing vectors

Geodesics

18	A conversion network for the tensors of General Relativity

19	Tetrads and the local system of reference - the Newman-Penrose formalism

20	Differentiating the spacetime metric, the tetrad, and their determinants, with respect to each other

21	The ThreePlusOne package and the 3 + 1 splitting of Einstein's equations

III. Transformations of coordinates

I. Spacetime and tensors in Physics

This section contains the information needed to compute with tensors in Classical and Quantum Mechanics, Electrodynamics and Special Relativity, using the Physics package. This material is also relevant for computing with tensors in General Relativity, for which there is a dedicated Section II: Curved spacetimes.

Default metric and signature, coordinate systems

To load Physics enter

>	$with (Physics)$

$[`*`, `.`, Annihilation, AntiCommutator, Antisymmetrize, Assume, Bra, Bracket, Check, Christoffel, Coefficients, Commutator, CompactDisplay, Coordinates, Creation, D_, Dagger, Decompose, Define, Dγ, Einstein, EnergyMomentum, Expand, ExteriorDerivative, Factor, FeynmanDiagrams, FeynmanIntegral, Fundiff, Geodesics, GrassmannParity, Gtaylor, Intc, Inverse, Ket, KillingVectors, KroneckerDelta, LagrangeEquations, LeviCivita, Library, LieBracket, LieDerivative, Normal, NumericalRelativity, Parameters, PerformOnAnticommutativeSystem, Projector, Psigma, Redefine, Ricci, Riemann, Setup, Simplify, SortProducts, SpaceTimeVector, StandardModel, Substitute, SubstituteTensor, SubstituteTensorIndices, SumOverRepeatedIndices, Symmetrize, TensorArray, Tetrads, ThreePlusOne, ToContravariant, ToCovariant, ToFieldComponents, ToSuperfields, Trace, TransformCoordinates, Vectors, Weyl, `^`, dAlembertian, d_, diff, g_, gamma_]$

(1)

By default, the spacetime metric is 4-dimensional, of Minkowski type, with the signature (- - - +). You can verify the metric, signature and dimension at any time in different ways, the simplest being:

$g_[]$

${g_}_{μ, ν} = ([\begin{array}{r} - 1 & 0 & 0 & 0 \\ 0 & - 1 & 0 & 0 \\ 0 & 0 & - 1 & 0 \\ 0 & 0 & 0 & 1 \end{array}])$

(2)

In Physics, everything is set up using the Setup command. Likewise, you can query one or several settings simultaneously using the same command, for example:

>	$Setup (coordinates, dimension, signature, metric)$

${g_}_{μ, ν} = ([\begin{array}{r} - 1 & 0 & 0 & 0 \\ 0 & - 1 & 0 & 0 \\ 0 & 0 & - 1 & 0 \\ 0 & 0 & 0 & 1 \end{array}])$

$_______________________________________________________$

$[coordinatesystems = none, dimension = 4, metric = \{(1, 1) = −1, (2, 2) = −1, (3, 3) = −1, (4, 4) = 1\}, signature = - - - +]$

(3)

The dimension, signature and metric, as well as all other Physics settings, can also be changed using Setup and Redefine. For example, to change the default signature you can enter $Setup (signature = `+++ -`)$ . To change the signature, reorder the coordinates and the lines and columns in the metric all in one go enter $Redefine (setall, tosignature = `+ + + -`)$ . The five signatures understood by Physics are:

a	(- - - +), default.

b	(+ - - - ), same line element as a.

c	(+ + + -), used in the ThreePlusOne package and ADM formalism, and in the database of exact solutions to Einstein equations.

d	(- + + +), same line element as c.

e	(+ + + +), used to set a Euclidean spacetime.

These signatures generalize naturally when you change the spacetime dimension.

In a flat spacetime, the value of the signature defines the signs in the line element

>	$g_[lineelement] &semi;$

$Systems of spacetime coordinates are: \{X = (x1, x2, x3, x4)\}$

$- {&DifferentialD; (x1)}^{2} - {&DifferentialD; (x2)}^{2} - {&DifferentialD; (x3)}^{2} + {&DifferentialD; (x4)}^{2}$

(4)

In a curved spacetime you can always define, at any point, a local system of reference of Minkowski type, also referred to in Maple as the tetrad system. The value of the signature defines the line element in that local system of reference.

The signature also indicates the position of the time-like component

>	$Library :- PositionOfTimelikeComponent () &semi;$

$4$

(5)

and therefore the ordering of lines and columns in the matrix representation of the metric (2).

To redefine a metric, the coordinates, or both according to a change you make in the signature you can use Setup or, more simply, use the Redefine command.

You can also visualize and change all the Physics settings at once using the Setup applet, launched entering $Setup ()$ . The following image shows the left half of that applet.

>	$Setup ()$

Systems of coordinates

A coordinate system is not set by default when you load the package. You can set it by indicating an uppercase letter that will work as a label representing the sequence of the four coordinates (this is internally implemented using alias).

>	$Setup (coordinates = X)$

$Systems of spacetime coordinates are: \{X = (x1, x2, x3, x4)\}$

$_______________________________________________________$

$[coordinatesystems = \{X\}]$

(6)

For historical reasons, to set coordinate systems there is also the Coordinates command, which can be used for the same purpose as Setup.

Setting a coordinate system is necessary when computing with curved spacetimes in order to compute the derivatives of the metric that enter the Christoffel symbols, which are then used to compute the components of all the general relativity tensors - an operation performed in the background, automatically, when you define the metric.

In a flat spacetime setting a coordinates system is optional, although it can be useful for different purposes as explained below.

The coordinates of the first system of coordinates you set are used by the d_, D_ and dAlembertian commands as the default differentiation variables.

You can define several coordinates systems at the same time

>	$Setup (coordinates = Y)$

$Systems of spacetime coordinates are: \{X = (x1, x2, x3, x4), Y = (y1, y2, y3, y4)\}$

$_______________________________________________________$

$[coordinatesystems = \{X, Y\}]$

(7)

To change the coordinates used by the differential operators d_, D_ and dAlembertian, for example from X to Y, enter $Setup (differentiationvariables = Y)$ .

All the coordinates of coordinates systems that are defined using Setup or Coordinates are automatically assumed to be real, so coulditbe, is and getassumptions, and through them all the Maple library, know about the coordinates' properties

>	$getassumptions (x2)$

$\{x2 :: real\}$

(8)

Often one works with Cartesian, spherical or cylindrical coordinates. These three keywords are understood by Setup and, when using any of them, you can, but do not need to, specify the label representing the coordinates. In that case, the label of the differentiation coordinates system is reused. If no coordinates system is defined then X is used. You can thus also set the coordinates via

>	$Setup (coordinates = spherical)$

$Default differentiation variables for d_, D_ and dAlembertian are: \{X = (r, θ, φ, t)\}$

$Systems of spacetime coordinates are: \{X = (r, θ, φ, t), Y = (y1, y2, y3, y4)\}$

$_______________________________________________________$

$[coordinatesystems = \{X, Y\}]$

(9)

Note that the coordinate t, complementing the three spherical coordinates, is positioned according to the signature (- - - +). To change the signature, see Setup. In the case of spherical and cylindrical coordinates, the assumptions automatically placed on them are the expected ones:

>	$map (getassumptions, [X])$

$[\{r :: [0, \infty)\}, \{θ :: [0, π]\}, \{φ :: [0, 2 π]\}, \{t :: [0, \infty)\}]$

(10)

Finally, you can also specify any coordinates to constitute a coordinates system and, in doing so, you can also redefine a previously used label. For example:

>	$Setup (coordinates = \{X = [u, v, w, t], Z = [z__1, z__2, z__3, z__4]\})$

$Systems of spacetime coordinates are: \{X = (u, v, w, t), Y = (y1, y2, y3, y4), Z = (z__1, z__2, z__3, z__4)\}$

$_______________________________________________________$

$[coordinatesystems = \{X, Y, Z\}]$

(11)

When the coordinates you define have specific geometrical meaning, e.g. (10), you can indicate that using the Assume command so that any restriction in their range is automatically taken into account, for example, when simplifying expressions.

•	Different uses of a coordinates system label

Due to the use of alias, the label of a coordinate system - say X - actually represents the sequence of the four coordinates, and so you can use this label to refer to all the coordinates at once, for example, when specifying the functionality of functions

$F (X)$

(12)

where $F (X)$ is a function of four variables. You can check the number of its operands, or get any one of its variables via

$nops ()$

$4$

(13)

>	$op (4, F (X))$

$t$

(14)

It is often useful to avoid a redundant display of the coordinate's dependency $(X)$ in functions. For that purpose use CompactDisplay.

>	$CompactDisplay (F (X))$

$F (u, v, w, t) will now be displayed as F$

(15)

The dependency of $F (X)$ is now omitted from the display

$F (X)$

(16)

$F (X)$

(17)

In Maple, the indices of tensors are represented through normal indexing []. Thus you can use the label of a coordinates system to represent the SpaceTimeVector

$X [mu]$

$X_{μ}$

(18)

In the context of Physics, contravariant indices are entered preceded by ~

>	$X [~ mu]$

$X_{}^{μ}$

(19)

The distinction between covariant and contravariant indices is relevant in non-Euclidean spacetimes (you can set the spacetime to be Euclidean by entering $Setup (metric = Euclidean)$ ). For example, in a flat Minkowski spacetime, when summing over the repeated indices of tensorial expressions (see SumOverRepeatedIndices)

>	$X {[mu]}^{2}$

$X_{μ} X_{}^{μ}$

(20)

>	$SumOverRepeatedIndices ()$

$t^{2} - u^{2} - v^{2} - w^{2}$

(21)

Defining more than one coordinates system is also convenient when transforming coordinates using the TransformCoordinates command, as explained in the next sections.

Tensors: their definition, symmetries and operations

Physics comes with a set of predefined tensors, mainly the spacetime metric $g_{μ, ν}$ , the space metric $γ_{j, k}$ , and all the standard tensors of General Relativity. To check their definition, index the tensor with the keyword definition, for example: $γ_{definition}$ . In addition, one of the strengths of Physics is that you can define tensors, in natural ways, by indicating a matrix or array with its components, or by indicating any generic tensorial expression involving other tensors.

In Maple tensor indices are letters, lowercase or uppercase, Latin or Greek, just like when computing with paper and pencil. The indices are entered using indexation, as in $A [mu]$ , and are displayed as subscripts as in $A_{μ}$ . To change or set the kind of letter (greek, lowercaselatin, etc.) used to represent a kind of index (spacetime, space, etc.) see Setup.

Contravariant indices are entered with ~ preceding the letter, as in $A [~ mu]$ , and are displayed as superscripts, as in $A_{}^{μ}$ . You can work with two or more kinds of indices at the same time, e.g., spacetime and space indices.

To input Greek letters you can spell them, as in mu for $μ$ , or simpler: use the shortcuts for entering Greek characters. Right-click your input and choose Convert To → 2-D Math input to give your spelled tensorial expression a textbook high-quality typesetting.

However, not every indexed object or function is automatically a tensor. You need to define it as such first with the Define command. You can do that in two ways:

1	Passing the tensor being defined, say $F_{μ, ν}$ , to the Define command, possibly indicating symmetries and/or antisymmetries for its indices.

2	Passing a tensorial equation where the left-hand side is the tensor being defined, as in item 1., and the right-hand side is a tensorial expression - or an Array or Matrix - such that the components of the tensor being defined become equal to the components of the tensorial expression.

After defining a tensor, say $F_{μ, ν}$ , you can perform the following operations on algebraic expressions involving it:

•	Automatic formatting of repeated indices, one covariant the other contravariant

•	Automatic handling of collisions of repeated indices in products of tensors

•	Simplify products using Einstein's sum rule for repeated indices

•	SumOverRepeatedIndices of the tensorial expression

•	Use TensorArray to compute the expression's components

•	TransformCoordinates

If you define a tensor using a tensorial equation you can additionally:

•	Get each tensor component by indexing, as in $A_{1}$ or $A_{}^{1}$

•	Get all the covariant and contravariant components by respectively using the shortcut notation $A []$ and $A [~]$

•	Use any of the special indexing keywords valid for the pre-defined tensors of Physics. They are definition, nonzero, and for tensors with 2 indices also trace and determinant

•	Forgo specifying the tensor dependency for differentiation purposes - it is inferred automatically from its definition

•	Redefine any particular tensor component using Library:-RedefineTensorComponent

•	Minimizing the number of independent tensor components using Library:-MinimizeTensorComponent

•	Compute the number of independent tensor components - relevant for tensors with many indices and different symmetries - using Library:-NumberOfTensorComponents

The following sections showcase these two ways of defining a tensor, the features described above, and the basic functionality in the Physics package for computing with tensors.

Defining a tensor by passing the tensor itself

The simplest way to define a spacetime or any other type of tensor is passing the tensor itself as a name indexed by one or several indices of the corresponding type.

By default, spacetime indices are represented by Greek letters

>	$restart &semi; with (Physics) &colon; Setup (spacetimeindices)$

$[spacetimeindices = greek]$

(22)

To change the type of letter used for a kind of index see Setup. Therefore, the simplest way to define a spacetime tensor is, for instance

>	$Define (A [mu])$

$Defined objects with tensor properties$

$\{A_{μ}, γ_{μ}, σ_{μ}, \partial_{μ}, g_{μ, ν}, ε_{α, β, μ, ν}\}$

(23)

The output of Define is always a set with all the tensors defined so far (it includes the predefined tensors, and all the coordinates systems as SpaceTimeVectors). To avoid the verbosity of Define's output use the quiet option.

To clear a tensor definition, like the one above, enter $Define (clear, A)$ .

Once $A_{μ}$ is defined as a tensor you can refer to any of its components by indexing with the corresponding covariant or contravariant number

$A [1]$

$A_{1}$

(24)

$A [~ 1]$

$A_{}^{1}$

(25)

To retrieve all the components at once you can use TensorArray or Library:-TensorComponents, the respective output will be an Array or a list

>	$TensorArray (A [mu])$

$[\begin{array}{c} A_{1} & A_{2} & A_{3} & A_{4} \end{array}]$

(26)

>	$Library :- TensorComponents (A [~ mu])$

$[A_{}^{1}, A_{}^{2}, A_{}^{3}, A_{}^{4}]$

(27)

When the spacetime is not Euclidean the repeated indices are automatically reformatted: one covariant the other contravariant

>	$A [mu] g_[mu, nu]$

$g_{μ, ν} A_{}^{μ}$

(28)

When the automatic choice of which one is contravariant is not the one you prefer, you can indicate your preference by using ~ for the contravariant one

>	$A [mu] g_[~ mu, nu]$

$A_{μ} {g_}_{ν, ~mu}$

(29)

Tensorial expressions, i.e. expressions that have any of the predefined tensors of Physics or tensors defined by you using Define, can be simplified using Simplify. That simplification takes into account the symmetry properties of tensorial subexpressions and makes use of the sum rule for repeated indices

>	$Simplify ()$

$A_{ν}$

(30)

Repeated indices - some or all - can be summed over using SumOverRepeatedIndices

>	$SumOverRepeatedIndices ()$

$g_{1, ν} A_{}^{1} + g_{2, ν} A_{}^{2} + g_{3, ν} A_{}^{3} + g_{4, ν} A_{}^{4}$

(31)

Recalling the current value of the metric

$g_[]$

${g_}_{μ, ν} = ([\begin{array}{r} - 1 & 0 & 0 & 0 \\ 0 & - 1 & 0 & 0 \\ 0 & 0 & - 1 & 0 \\ 0 & 0 & 0 & 1 \end{array}])$

(32)

a tensor array with the components of, for example, the relationship $A_{ν} = g_{μ, ν} A_{}^{μ}$ , can be computed using TensorArray

>	$TensorArray (A_{ν} = g_{μ, ν} A_{}^{μ})$

$[\begin{array}{c} A_{1} = - A_{~1} & A_{2} = - A_{~2} & A_{3} = - A_{~3} & A_{4} = A_{~4} \end{array}]$

(33)

Note the textbook typesetting of the input above. That input line includes subscripts and superscripts for the tensor indices. You can achieve this input with typesetting by entering the expression using standard Maple notation, as in: $TensorArray (A [nu] = g_[mu, nu] A [~ mu])$ , then right-clicking the expression and following the pop-up menu 2-D Math → Convert To → 2-D Math input. This is particularly useful:

1	when the input and output are the same so you can terminate the input with : to avoid displaying the output,

2	when the input without typesetting is not easy to read/understand

3	for presentation purposes.

When you perform a coordinate transformation, tensors change according to specific rules. For that purpose, start by setting two coordinate systems, as shown in the previous section

>	$Coordinates (X = [u, v, w, t], Z = [z__1, z__2, z__3, z__4])$

$Systems of spacetime coordinates are: \{X = (u, v, w, t), Z = (z__1, z__2, z__3, z__4)\}$

$\{X, Z\}$

(34)

You can now transform coordinates using TransformCoordinates, for example from X to Z using $\{u = z__1 + z__2, v = z__1 - z__2\}$ , as follows:

>	$tr ≔ \{u = z__1 + z__2, v = z__1 - z__2\} &colon;$

>	$TransformCoordinates (tr, A [mu])$

$[\begin{array}{c} A_{1} + A_{2} \\ A_{1} - A_{2} \\ A_{3} \\ A_{4} \end{array}]$

(35)

Note the different transformation rule for the covariant components (above) and the contravariant ones:

>	$TransformCoordinates (tr, A [~ mu])$

$[\begin{array}{c} \frac{1}{2} A_{~1} + \frac{1}{2} A_{~2} \\ \frac{1}{2} A_{~1} - \frac{1}{2} A_{~2} \\ A_{~3} \\ A_{~4} \end{array}]$

(36)

Defining a tensor by passing a tensorial equation

Tensors defined by passing a tensorial equation have all the features mentioned in the previous section, which enable you to Simplify, SumOverRepeatedIndices, TensorArray, and TransformCoordinates, as well as several additional ones.

A simple example is that of a 4-vector. This time, we also want to specify its components. You can indicate them in a list on the right-hand side of the definition

>	$Define (p [μ] = [p__x, p__y, p__z, \frac{E}{c}])$

$Defined objects with tensor properties$

$\{A_{μ}, γ_{μ}, σ_{μ}, \partial_{μ}, g_{μ, ν}, p_{μ}, ε_{α, β, μ, ν}, X_{μ}, Z_{μ}\}$

(37)

On the right-hand side of the definition you can also use a Vector construction, as in $⟨p__x, p__y, p__z, \frac{E}{c}⟩$ , or a Matrix. See Define for all the possible ways you can use to indicate the components.

Having defined p passing a tensorial equation, you can now get each of its components via indexing

$p [1]$

$p__x$

(38)

$p [0]$

$\frac{E}{c}$

(39)

Note that the value 0 of the index points to the position of the timelike component, that is, the position of the different sign in the signature. You can query that using Setup

>	$Setup (signature)$

$[signature = - - - +]$

(40)

or Library:-PositionOfTimelikeComponent

>	$Library :- PositionOfTimelikeComponent ()$

$4$

(41)

When the tensor is defined using a tensorial equation and a coordinates system is set you can also use the coordinates as tensor indices to select tensor components. For example,

>	$Setup (coordinates = cartesian, usecoordinates = true)$

$* Partial match of ' usecoordinates' against keyword ' usecoordinatesastensorindices'$

$Default differentiation variables for d_, D_ and dAlembertian are: \{X = (x, y, z, t)\}$

$Systems of spacetime coordinates are: \{X = (x, y, z, t), Z = (z__1, z__2, z__3, z__4)\}$

$_______________________________________________________$

$[coordinatesystems = \{X, Z\}, usecoordinatesastensorindices = true]$

(42)

>	$p [1] = p [x]$

$p__x = p__x$

(43)

>	$p [4] = p [t]$

$\frac{E}{c} = \frac{E}{c}$

(44)

You can get all the covariant and contravariant components by respectively using the following shortcut notation

$p []$

$p_{μ} = ([\begin{array}{c} p__x & p__y & p__z & \frac{E}{c} \end{array}])$

(45)

$p [~]$

$p_{~mu} = ([\begin{array}{c} - p__x & - p__y & - p__z & \frac{E}{c} \end{array}])$

(46)

The indexing keywords valid for all the pre-defined tensors of Physics, definition, determinant, nonzero, and trace, can also be used for tensors you define using tensorial equations

>	$p [definition]$

$p_{μ} = [p__x, p__y, p__z, \frac{E}{c}]$

(47)

>	$p [nonzero]$

$p_{μ} = \{1 = p__x, 2 = p__y, 3 = p__z, 4 = \frac{E}{c}\}$

(48)

The trace and determinant keywords are only for tensors with two indices. To illustrate this, first define a tensor by indicating a 2x2 generic matrix

>	$F [mu, nu] = Matrix (4, symbol = F)$

$F_{μ, ν} = ([\begin{array}{c} F_{1, 1} & F_{1, 2} & F_{1, 3} & F_{1, 4} \\ F_{2, 1} & F_{2, 2} & F_{2, 3} & F_{2, 4} \\ F_{3, 1} & F_{3, 2} & F_{3, 3} & F_{3, 4} \\ F_{4, 1} & F_{4, 2} & F_{4, 3} & F_{4, 4} \end{array}])$

(49)

>	$Define ()$

$Defined objects with tensor properties$

$\{A_{μ}, γ_{μ}, F_{μ, ν}, σ_{μ}, \partial_{μ}, g_{μ, ν}, p_{μ}, ε_{α, β, μ, ν}, X_{μ}, Z_{μ}\}$

(50)

$F [~]$

$F_{~mu, ~nu} = ([\begin{array}{c} F_{1, 1} & F_{1, 2} & F_{1, 3} & - F_{1, 4} \\ F_{2, 1} & F_{2, 2} & F_{2, 3} & - F_{2, 4} \\ F_{3, 1} & F_{3, 2} & F_{3, 3} & - F_{3, 4} \\ - F_{4, 1} & - F_{4, 2} & - F_{4, 3} & F_{4, 4} \end{array}])$

(51)

>	$F [mu, mu] = F [trace]$

$F_{μ}^{μ} = - F_{1, 1} - F_{2, 2} - F_{3, 3} + F_{4, 4}$

(52)

>	$F [determinant]$

$F_{1, 1} F_{2, 2} F_{3, 3} F_{4, 4} - F_{1, 1} F_{2, 2} F_{3, 4} F_{4, 3} - F_{1, 1} F_{2, 3} F_{3, 2} F_{4, 4} + F_{1, 1} F_{2, 3} F_{3, 4} F_{4, 2} + F_{1, 1} F_{2, 4} F_{3, 2} F_{4, 3} - F_{1, 1} F_{2, 4} F_{3, 3} F_{4, 2} - F_{1, 2} F_{2, 1} F_{3, 3} F_{4, 4} + F_{1, 2} F_{2, 1} F_{3, 4} F_{4, 3} + F_{1, 2} F_{2, 3} F_{3, 1} F_{4, 4} - F_{1, 2} F_{2, 3} F_{3, 4} F_{4, 1} - F_{1, 2} F_{2, 4} F_{3, 1} F_{4, 3} + F_{1, 2} F_{2, 4} F_{3, 3} F_{4, 1} + F_{1, 3} F_{2, 1} F_{3, 2} F_{4, 4} - F_{1, 3} F_{2, 1} F_{3, 4} F_{4, 2} - F_{1, 3} F_{2, 2} F_{3, 1} F_{4, 4} + F_{1, 3} F_{2, 2} F_{3, 4} F_{4, 1} + F_{1, 3} F_{2, 4} F_{3, 1} F_{4, 2} - F_{1, 3} F_{2, 4} F_{3, 2} F_{4, 1} - F_{1, 4} F_{2, 1} F_{3, 2} F_{4, 3} + F_{1, 4} F_{2, 1} F_{3, 3} F_{4, 2} + F_{1, 4} F_{2, 2} F_{3, 1} F_{4, 3} - F_{1, 4} F_{2, 2} F_{3, 3} F_{4, 1} - F_{1, 4} F_{2, 3} F_{3, 1} F_{4, 2} + F_{1, 4} F_{2, 3} F_{3, 2} F_{4, 1}$

(53)

To work with the determinant without having it computed you can use the inert version of the tensor and activate the computation only when that is desired using value

>	$%F [determinant]$

${%F}_{determinant}$

(54)

>	$value ()$

(55)

The matrix keyword shows the matrix form that corresponds to the indicated indices, which is particularly useful when the indices are a mixture of covariant and contravariant

>	$F [~ mu, nu, matrix]$

$F_{~mu, ν} = ([\begin{array}{c} - F_{1, 1} & - F_{1, 2} & - F_{1, 3} & - F_{1, 4} \\ - F_{2, 1} & - F_{2, 2} & - F_{2, 3} & - F_{2, 4} \\ - F_{3, 1} & - F_{3, 2} & - F_{3, 3} & - F_{3, 4} \\ F_{4, 1} & F_{4, 2} & F_{4, 3} & F_{4, 4} \end{array}])$

(56)

All these keywords work the same way in the case of a curved spacetime.

You can redefine any tensor component using Library:-RedefineTensorComponent, for example redefine $F_{2, 1} = - F_{1, 2}$

>	$Library :- RedefineTensorComponent (F [2, 1] = - F [1, 2])$

$F_{μ, ν} = ([\begin{array}{c} F_{1, 1} & F_{1, 2} & F_{1, 3} & F_{1, 4} \\ - F_{1, 2} & F_{2, 2} & F_{2, 3} & F_{2, 4} \\ F_{3, 1} & F_{3, 2} & F_{3, 3} & F_{3, 4} \\ F_{4, 1} & F_{4, 2} & F_{4, 3} & F_{4, 4} \end{array}])$

(57)

When you define a tensor you can also minimize the number of its independent components all in one go. Consider for instance redoing the definition of $F_{μ, ν},$ this time indicating that it is antisymmetric and minimizing the amount of independent components by taking that fact into account

>	$Define (, antisymmetric, minimizetensorcomponents)$

$Defined objects with tensor properties$

$\{A_{μ}, γ_{μ}, F_{μ, ν}, σ_{μ}, \partial_{μ}, g_{μ, ν}, p_{μ}, ε_{α, β, μ, ν}, X_{μ}, Z_{μ}\}$

(58)

$F []$

$F_{μ, ν} = ([\begin{array}{c} 0 & F_{1, 2} & F_{1, 3} & F_{1, 4} \\ - F_{1, 2} & 0 & F_{2, 3} & F_{2, 4} \\ - F_{1, 3} & - F_{2, 3} & 0 & F_{3, 4} \\ - F_{1, 4} & - F_{2, 4} & - F_{3, 4} & 0 \end{array}])$

(59)

>	$Library :- NumberOfIndependentTensorComponents (F)$

$6$

(60)

•	Defining tensors that represent tensorial expressions

One of the most useful features of defining tensors using tensorial equations is that the right-hand side of the equation can be any desired tensorial expression, not just a list or table of components. For example, at this point we have defined the tensor $A_{μ}$

>	$Library :- TensorComponents (A_{μ})$

$[A_{1}, A_{2}, A_{3}, A_{4}]$

(61)

Taking $A_{μ}$ to represent the 4D potential in electrodynamics, the corresponding electromagnetic field is

>	$F [mu, nu] = 2 \cdot Antisymmetrize (d_[mu] (A [nu] (X)))$

$F_{μ, ν} = \partial_{μ} (A_{ν} (X)) - \partial_{ν} (A_{μ} (X))$

(62)

To have a compact display that avoids redundancy use CompactDisplay

>	$CompactDisplay (A (X))$

$A (x, y, z, t) will now be displayed as A$

(63)

Now redo the definition of $F_{μ, ν}$ using (62)

>	$Define (redo,, minimizetensorcomponents)$

$Defined objects with tensor properties$

$\{A_{μ}, γ_{μ}, F_{μ, ν}, σ_{μ}, \partial_{μ}, g_{μ, ν}, p_{μ}, ε_{α, β, μ, ν}, X_{μ}, Z_{μ}\}$

(64)

$F []$

$F_{μ, ν} = ([\begin{array}{c} 0 & \frac{\partial}{\partial x} A_{2} (x, y, z, t) - (\frac{\partial}{\partial y} A_{1} (x, y, z, t)) & \frac{\partial}{\partial x} A_{3} (x, y, z, t) - (\frac{\partial}{\partial z} A_{1} (x, y, z, t)) & \frac{\partial}{\partial x} A_{4} (x, y, z, t) - (\frac{\partial}{\partial t} A_{1} (x, y, z, t)) \\ \frac{\partial}{\partial y} A_{1} (x, y, z, t) - (\frac{\partial}{\partial x} A_{2} (x, y, z, t)) & 0 & \frac{\partial}{\partial y} A_{3} (x, y, z, t) - (\frac{\partial}{\partial z} A_{2} (x, y, z, t)) & \frac{\partial}{\partial y} A_{4} (x, y, z, t) - (\frac{\partial}{\partial t} A_{2} (x, y, z, t)) \\ \frac{\partial}{\partial z} A_{1} (x, y, z, t) - (\frac{\partial}{\partial x} A_{3} (x, y, z, t)) & \frac{\partial}{\partial z} A_{2} (x, y, z, t) - (\frac{\partial}{\partial y} A_{3} (x, y, z, t)) & 0 & \frac{\partial}{\partial z} A_{4} (x, y, z, t) - (\frac{\partial}{\partial t} A_{3} (x, y, z, t)) \\ \frac{\partial}{\partial t} A_{1} (x, y, z, t) - (\frac{\partial}{\partial x} A_{4} (x, y, z, t)) & \frac{\partial}{\partial t} A_{2} (x, y, z, t) - (\frac{\partial}{\partial y} A_{4} (x, y, z, t)) & \frac{\partial}{\partial t} A_{3} (x, y, z, t) - (\frac{\partial}{\partial z} A_{4} (x, y, z, t)) & 0 \end{array}])$

(65)

Note that the derivatives - constructed using the diff command - are compactly displayed in index notation.

Another common situation where defining a tensor by using a tensorial expression is useful is constructing a traceless tensor from a given one. For example, in the case of a tensor with 2 indices $C_{α, β}$ ,

>	$C_{α, β} = Matrix (4, symbol = C)$

$C_{α, β} = ([\begin{array}{c} C_{1, 1} & C_{1, 2} & C_{1, 3} & C_{1, 4} \\ C_{2, 1} & C_{2, 2} & C_{2, 3} & C_{2, 4} \\ C_{3, 1} & C_{3, 2} & C_{3, 3} & C_{3, 4} \\ C_{4, 1} & C_{4, 2} & C_{4, 3} & C_{4, 4} \end{array}])$

(66)

>	$Define ()$

$Defined objects with tensor properties$

$\{A_{μ}, C_{α, β}, γ_{μ}, F_{μ, ν}, σ_{μ}, \partial_{μ}, g_{μ, ν}, p_{μ}, ε_{α, β, μ, ν}, X_{μ}, Z_{μ}\}$

(67)

>	$T [α, β] = C [α, β] - \frac{C [μ, μ] \cdot g_[α, β]}{4}$

$T_{α, β} = C_{α, β} - \frac{g_{α, β} C_{μ}^{μ}}{4}$

(68)

>	$Define ()$

$Defined objects with tensor properties$

$\{A_{μ}, C_{α, β}, γ_{μ}, F_{μ, ν}, σ_{μ}, T_{α, β}, \partial_{μ}, g_{μ, ν}, p_{μ}, ε_{α, β, μ, ν}, X_{μ}, Z_{μ}\}$

(69)

$T []$

$T_{μ, ν} = ([\begin{array}{c} \frac{3}{4} C_{1, 1} - \frac{1}{4} C_{2, 2} - \frac{1}{4} C_{3, 3} + \frac{1}{4} C_{4, 4} & C_{1, 2} & C_{1, 3} & C_{1, 4} \\ C_{2, 1} & \frac{3}{4} C_{2, 2} - \frac{1}{4} C_{1, 1} - \frac{1}{4} C_{3, 3} + \frac{1}{4} C_{4, 4} & C_{2, 3} & C_{2, 4} \\ C_{3, 1} & C_{3, 2} & \frac{3}{4} C_{3, 3} - \frac{1}{4} C_{1, 1} - \frac{1}{4} C_{2, 2} + \frac{1}{4} C_{4, 4} & C_{3, 4} \\ C_{4, 1} & C_{4, 2} & C_{4, 3} & \frac{3}{4} C_{4, 4} + \frac{1}{4} C_{1, 1} + \frac{1}{4} C_{2, 2} + \frac{1}{4} C_{3, 3} \end{array}])$

(70)

>	$T [alpha, alpha] = T [trace]$

$T_{α}^{α} = 0$

(71)

Automatic formatting of repeated tensor indices and handling of their collisions in products

The distinction between covariant and contravariant indices in the input of tensors is made by prefixing contravariant indices with ~, as in ~mu. In the output, contravariant indices are displayed as superscripts. However, for contracted tensor indices it is not relevant which one is covariant and which one contravariant. Taking advantage of that, contracted indices can both be entered (input) as covariant, in which case they will be automatically rewritten as one covariant and one contravariant. You can override this behavior by indicating which index you want to be contravariant in the output

>	$restart &semi; with (Physics) &colon;$

Define two tensors

>	$Define (A [mu], B [mu])$

$Defined objects with tensor properties$

$\{A_{μ}, B_{μ}, γ_{μ}, σ_{μ}, \partial_{μ}, g_{μ, ν}, ε_{α, β, μ, ν}\}$

(72)

The contraction of A with itself and with B can be entered with all repeated indices as covariant - the output shows these indices reformatted appropriately

>	$A {[mu]}^{2}$

$A_{μ} A_{}^{μ}$

(73)

>	$A [mu] B [mu]$

$A_{μ} B_{}^{μ}$

(74)

Entering all the repeated indices as covariant not only removes the burden of having to type one index as contravariant each time there is a contraction, it also automatically results in a normal form for a contraction that the system remembers, so the indices are always reformatted in the same way.

In cases where the choice, made by the system, of which index is contravariant is not the one you prefer, you can override the system's choice by indicating your preference using ~ to prefix the contravariant index. For example

>	$A [~ mu] B [mu]$

$A_{}^{μ} B_{μ}$

(75)

•	Automatic handling of collisions of contracted indices in products Consider two tensorial expressions, say $E__1$ and $E__2$ , that have the same contracted indices, for example (74) and (75)

$E__1 ≔$

$E__1 ≔ A_{μ} B_{}^{μ}$

(76)

$E__2 ≔$

$E__2 ≔ A_{}^{μ} B_{μ}$

(77)

If you multiply $E__1 \cdot E__2$ there shouldn't be any problem. However, from the point of view of the summation rule for repeated indices the index $μ$ would be repeated four times, which is incorrect; we say this is a case of collision of indices in products. These cases are handled automatically by replacing the (dummy) repeated indices in one of the factors such that every contracted index is repeated only once. For example, we see in the following input/output that the repeated index $μ$ in $E__2$ is replaced by $ν$

>	$E__1 \cdot E__2$

$A_{μ} B_{}^{μ} A_{}^{ν} B_{ν}$

(78)

This expression now has two pairs of repeated indices and checks out

>	$Check ()$

$The repeated and free indices in the given expression check ok.$

(79)

Therefore, multiplying it by itself should not be a problem

$2$

$A_{μ} B_{}^{μ} A_{}^{ν} B_{ν} A_{α} B_{}^{α} A_{}^{β} B_{β}$

(80)

>	$Check ()$

$The repeated and free indices in the given expression check ok.$

(81)

Note that a collision of indices in products can also happen between a free index in one factor and a repeated index in another factor. Those cases are also handled automatically, for example

$E__1$

$A_{μ} B_{}^{μ}$

(82)

>	$A [mu] \cdot E__1$

$A_{μ} A_{ν} B_{}^{ν}$

(83)

When introducing replacements to resolve the collision of repeated indices in products, special care is taken such that the introduced indices:

a	are of the same kind as the ones being replaced;

b	were not already present in the expression where they are being introduced;

To prevent the system from introducing a certain index, say $ν$ , before multiplying $E__1 \cdot E__2$ you can assign it to _Env_Physics_indices_in_use

>	$_Env_Physics_indices_in_use ≔ nu$

$_Env_Physics_indices_in_use ≔ ν$

(84)

Now you have

>	$E__1 \cdot E__2$

$A_{μ} B_{}^{μ} A_{}^{α} B_{α}$

(85)

>	$_Env_Physics_indices_in_use ≔ nu, alpha$

$_Env_Physics_indices_in_use ≔ ν, α$

(86)

>	$E__1 \cdot E__2$

$A_{μ} B_{}^{μ} A_{}^{β} B_{β}$

(87)

Tensor symmetries

Your definition of a tensor can include symmetries and antisymmetries for its indices. For a totally symmetric or antisymmetric tensor it suffices to add the corresponding keyword symmetric or antisymmetric.

>	$restart &semi; with (Physics) &colon;$

>	$Define (B [mu, nu], symmetric)$

$Defined objects with tensor properties$

$\{B_{μ, ν}, γ_{μ}, σ_{μ}, \partial_{μ}, g_{μ, ν}, ε_{α, β, μ, ν}\}$

(88)

When defining a tensor this way, without passing a tensorial equation or the keyword minimizetensorcomponents, the symmetry indicated is not automatically taken into account. That allows for further abstract manipulations, and when you want the symmetry to be taken into account you can use Simplify

>	$B [mu, nu] - B [nu, mu]$

$B_{μ, ν} - B_{ν, μ}$

(89)

>	$Simplify ()$

$0$

(90)

Alternatively, by passing the keyword minimizetensorcomponents the symmetry indicated is automatically taken into account

>	$Define (B [mu, nu], symmetric, minimizetensorcomponents)$

$Defined objects with tensor properties$

$\{B_{μ, ν}, γ_{μ}, σ_{μ}, \partial_{μ}, g_{μ, ν}, ε_{α, β, μ, ν}\}$

(91)

>	$B [mu, nu] - B [nu, mu]$

$0$

(92)

Consider now a tensor with four indices $R_{α, β, μ, ν}$ which has the symmetries of the Riemann tensor. This tensor is antisymmetric with respect to interchanging the positions of $α \leftrightarrow β$ or $μ \leftrightarrow ν$ , and symmetric with respect to interchanging the positions of the 1^st and 2^nd pairs of indices $[α, β]$ ↔ $[μ, ν]$ . You can indicate these symmetries by specifying the indices themselves or their numerical position

>	$Define (R [α, β, μ, ν], symmetric = \{\{[α, β], [μ, ν]\}\}, antisymmetric = \{\{α, β\}, \{μ, ν\}\})$

$Defined objects with tensor properties$

$\{B_{μ, ν}, γ_{μ}, σ_{μ}, R_{α, β, μ, ν}, \partial_{μ}, g_{μ, ν}, ε_{α, β, μ, ν}\}$

(93)

To retrieve the symmetries of a tensor, use Library:-GetTensorSymmetryProperties

>	$Library :- GetTensorSymmetryProperties (R)$

$\{[[1, 2], [3, 4]]\}, \{[1, 2], [3, 4]\}$

(94)

Redoing the definition of $R_{α, β, μ, ν}$ , this time using minimizetensorcomponents, allows, among other things, for counting of the number of independent components of R

>	$Define (R [α, β, μ, ν], symmetric = \{\{[α, β], [μ, ν]\}\}, antisymmetric = \{\{α, β\}, \{μ, ν\}\}, minimizetensorcomponents)$

$Defined objects with tensor properties$

$\{B_{μ, ν}, γ_{μ}, σ_{μ}, R_{μ, ν, α, β}, \partial_{μ}, g_{μ, ν}, ε_{α, β, μ, ν}\}$

(95)

Out of the $4^{4} = 256$ components only 21 are independent, due to the symmetries indicated

>	$Library :- NumberOfIndependentTensorComponents (R)$

$21$

(96)

In the case of the Riemann tensor, taking into account the first Bianchi identity, this number is further reduced to 20.

•	Traceless tensors

As previously mentioned, you can use tensorial equations to define tensors representing arbitrary tensorial expressions that involve other tensors. A more advanced example of that is the construction of a traceless version of $R_{α, β, μ, ν}$ , the tensor with the symmetries of the Riemann tensor defined in the previous section. For this tensor, the sum over any possible pair of repeated indices (contraction of two indices) returns 0. The formula used is the same as the one used to define the Weyl tensor in terms of the Riemann and Ricci tensors

>	$Weyl [definition]$

$C_{α, β, μ, ν} = R_{α, β, μ, ν} - \frac{R_{α, μ} g_{β, ν}}{2} + \frac{R_{α, ν} g_{β, μ}}{2} + \frac{R_{β, μ} g_{α, ν}}{2} - \frac{R_{β, ν} g_{α, μ}}{2} + (\frac{g_{α, μ} g_{β, ν}}{6} - \frac{g_{α, ν} g_{β, μ}}{6}) R_{κ}^{κ}$

(97)

Converting it to Riemann, without evaluating tensors, and substituting Riemann with R and Weyl with W, you get

>	$subs (Riemann = R, Weyl = W, convert (Weyl [definition], Riemann, only = \{Ricci\}, evaluatetensor = false))$

$W_{α, β, μ, ν} = R_{α, β, μ, ν} - \frac{R_{α, κ, μ}^{κ} g_{β, ν}}{2} + \frac{R_{α, κ, ν}^{κ} g_{β, μ}}{2} + \frac{R_{β, κ, μ}^{κ} g_{α, ν}}{2} - \frac{R_{β, κ, ν}^{κ} g_{α, μ}}{2} + (\frac{g_{α, μ} g_{β, ν}}{6} - \frac{g_{α, ν} g_{β, μ}}{6}) R_{κ, λ}^{λ κ}$

(98)

Now define $W_{α, β, μ, ν}$ using this tensorial equation

>	$Define (, minimizetensorcomponents)$

$Defined objects with tensor properties$

$\{B_{μ, ν}, γ_{μ}, σ_{μ}, R_{μ, ν, α, β}, W_{α, β, μ, ν}, \partial_{μ}, g_{μ, ν}, ε_{α, β, μ, ν}\}$

(99)

While the number of independent components of R is 21, W only has the expected 10 and is traceless

>	$Library :- NumberOfIndependentTensorComponents (W)$

$10$

(100)

>	$W_{α, μ, ν}^{α}$

$0$

(101)

•	Symmetrization and Antisymmetrization of tensors

You can create new tensorial expressions by symmetrizing or antisymmetrizing existing tensors or tensorial expressions, with respect to all or part of their free indices. The resulting tensorial expressions can be used to define new tensors with the corresponding symmetries. For example, construct a tensorial expression by symmetrizing $W_{α, β, μ, ν}$ with respect to $α \leftrightarrow μ$ and antisymmetrizing the result with respect to $β \leftrightarrow μ$ , then define a new tensor $U_{α, β, μ, ν}$ using the resulting tensorial expression. Note that $U_{α, β, μ, ν}$ will also have the symmetries and tracelessness of $W_{α, β, μ, ν}$ .

>	$Symmetrize (W_{α, β, μ, ν}, [α, μ])$

$\frac{W_{α, β, μ, ν}}{2} - \frac{W_{β, μ, α, ν}}{2}$

(102)

>	$U_{α, β, μ, ν} = Antisymmetrize (, [β, μ])$

$U_{α, β, μ, ν} = \frac{W_{α, β, μ, ν}}{4} - \frac{W_{β, μ, α, ν}}{2} - \frac{W_{α, μ, β, ν}}{4}$

(103)

>	$Define (, minimizetensorcomponents)$

$Defined objects with tensor properties$

$\{B_{μ, ν}, γ_{μ}, σ_{μ}, R_{μ, ν, α, β}, U_{α, β, μ, ν}, W_{α, β, μ, ν}, \partial_{μ}, g_{μ, ν}, ε_{α, β, μ, ν}\}$

(104)

The number of independent tensor components of $U_{α, β, μ, ν}$ is

>	$Library :- NumberOfIndependentTensorComponents (U)$

$8$

(105)

Substituting tensors and tensor indices

Two common operations with tensorial expressions are substituting tensors and substituting tensor indices. The Physics commands for these purposes are SubstituteTensor and SubstituteTensorIndices.

>	$restart &semi; with (Physics) &colon;$

>	$Define (A, B, C, F, G)$

$Defined objects with tensor properties$

$\{A, B, C, F, G, γ_{μ}, σ_{μ}, \partial_{μ}, g_{μ, ν}, ε_{α, β, μ, ν}\}$

(106)

>	$EQ ≔ A [μ] = G [ν, α] A [α] F [μ, ν]$

$EQ ≔ A_{μ} = G_{ν, α} A_{}^{α} F_{μ}^{ν}$

(107)

The repeated and free indices of the left and right-hand sides of this equation are

>	$Check (EQ, all)$

$The repeated indices per term are: [\{...\}, \{...\}, ...], the free indices are: \{...\}$

$([\emptyset], \{μ\}) = ([\{α, ν\}], \{μ\})$

(108)

The easy case: using EQ to substitute $A [μ]$ in $A [μ]$ itself

>	$SubstituteTensor (EQ, A [μ])$

$G_{ν, α} A_{}^{α} F_{μ}^{ν}$

(109)

The same operation, but now the free index in the target expression is $ν$ instead of $μ$

>	$SubstituteTensor (EQ, A [ν])$

$G_{β, α} A_{}^{α} F_{ν}^{β}$

(110)

The same operation, but now the target is $A_{}^{ν}$

>	$SubstituteTensor (EQ, A_{}^{ν})$

$G_{β, α} A_{}^{α} F_{}^{ν, β}$

(111)

An example where the index $ν$ , which is repeated in the right-hand side of EQ, is also repeated in the target expression:

>	$ee ≔ A [ν] A [ν]$

$ee ≔ A_{ν} A_{}^{ν}$

(112)

The collision of indices is resolved automatically

>	$res ≔ SubstituteTensor (EQ, ee)$

$res ≔ G_{λ, κ} A_{}^{κ} F_{ν}^{λ} G_{β, α} A_{}^{α} F_{}^{ν, β}$

(113)

The repeated and free indices of this result are

>	$Check (res, all)$

$The repeated indices per term are: [\{...\}, \{...\}, ...], the free indices are: \{...\}$

$[\{α, β, κ, λ, ν\}], \emptyset$

(114)

The functionality of tensor functions is also considered a parameter when substituting tensors. For example, consider the following substitution equation

>	$EQ__2 ≔ A [μ] (X) = B [μ] (X)$

$EQ__2 ≔ A_{μ} (X) = B_{μ} (X)$

(115)

Now substitute in $A_{ν} (Y)$

>	$SubstituteTensor (EQ__2, A_{ν} (Y))$

$B_{ν} (Y)$

(116)

SubstituteTensor also substitutes sub-expressions like algsubs. For example

>	$EQ__3 ≔ A [μ] (X) B [ν] (Y) = G [μ, ν] (X)$

$EQ__3 ≔ A_{μ} (X) B_{ν} (Y) = G_{μ, ν} (X)$

(117)

The target expression is

>	$A [α] (X) B [β] (Y) A [ρ] (X) B [ρ] (Y)$

$A_{α} (X) B_{β} (Y) A_{ρ} (X) B_{}^{ρ} (Y)$

(118)

When substituting $EQ__3$ into (118), the sub-expression $A \cdot B$ appears twice, once with repeated indices and once without, and is not part of the indeterminates of (118)

>	$indets ()$

$\{X, Y, A_{α} (X), A_{ρ} (X), B_{β} (Y), B_{}^{ρ} (Y)\}$

(119)

>	$SubstituteTensor (EQ__3,)$

$G_{α, β} (X) G_{ρ}^{ρ} (X)$

(120)

•	Tensor indices can be substituted in a similar way

Consider the following target tensorial expression

>	$ee__1 ≔ g_[α, μ] A [~mu] g_[~alpha, ~nu] C [ν, σ, ~rho]$

$ee__1 ≔ g_{α, μ} A_{}^{μ} g_{}^{α, ν} C_{ν, σ}^{ρ}$

(121)

>	$Check (ee__1, all)$

$The repeated indices per term are: [\{...\}, \{...\}, ...], the free indices are: \{...\}$

$[\{α, μ, ν\}], \{σ, ~rho\}$

(122)

Substitute the repeated index $α$ that appears in covariant and contravariant forms in $ee__1$

>	$SubstituteTensorIndices (α = β, ee__1)$

$g_{β, μ} A_{}^{μ} g_{}^{β, ν} C_{ν, σ}^{ρ}$

(123)

Now substitute the contravariant index $~ ρ = ~ β &colon;$ a) you don't need to prefix contravariant indices with ~ in the substitution equations; and b) the index $β$ already exists as a dummy (repeated) index in the target expression; you don't need to be concerned with that, this kind of collision of indices is also handled automatically

>	$SubstituteTensorIndices (ρ = β, ee__1)$

$g_{α, μ} A_{}^{μ} g_{}^{α, ν} C_{ν, σ}^{β}$

(124)

To substitute several indices at once, enclose the substitution equations in a set or a list

>	$SubstituteTensorIndices ([ρ = β, α = γ], ee__1)$

$g_{γ, μ} A_{}^{μ}$

Maple

Maple 附加模块

MapleSim

MapleSim 附加模块

系统工程

项目服务

Maple T.A. and Möbius

教育

行业

汽车与航空航天

机器人

机器设计和工业自动化

其他

应用领域

产品价格

购买

院系/全校正版授权

Maplesoft精英维护升级计划

支持

产品培训

产品在线帮助

研讨会与活动

出版

资源中心

示例和应用

社区

关于 Maplesoft

媒体中心

用户社区

联系我们

Online Help

All Products Maple MapleSim

Maple

数学软件

Maple 附加模块

MapleSim

多学科系统级建模仿真

MapleSim 附加模块

系统工程

项目服务

Maple T.A. and Möbius

教育

行业

汽车与航空航天

机器人

机器设计和工业自动化

其他

应用领域

产品价格

购买

院系/全校正版授权

Maplesoft精英维护升级计划

支持

产品培训

产品在线帮助

研讨会与活动

出版

资源中心

示例和应用

社区

关于 Maplesoft

媒体中心

用户社区

联系我们

Online Help

All Products Maple MapleSim