If a module has an export or local named ModulePrint, the result of the ModulePrint() command is displayed instead of the module when a command in that module is executed.

ModulePrint is analogous to the user-defined function formatting facility described in ?print, except no arguments are passed to the formatting function.

LinkedList := module()
    option package;
    export New, Prepend;
    local DisplayNode;

    New := proc( data )
    module()
        export Val, Next;
            local ModulePrint;

        Val := data;
        Next := 0;

            ModulePrint := proc()
               DisplayNode(thismodule);
            end proc;
    end module;
    end proc;

    Prepend := proc( llist, val )
        local node;
        node := New(val);
        node:-Next := eval(llist);
        return node;
    end proc;

    DisplayNode := proc( node )
    if node = 0 then
        return NULL;
    else
        return node:-Val, DisplayNode(node:-Next);
    end if;
    end proc;

end module:

$\mathrm{with}\left(\mathrm{LinkedList}\right)$

$\left[\mathrm{New}\,\mathrm{Prepend}\right]$

$l≔\mathrm{LinkedList}:-\mathrm{New}\left(x\right)$

$l≔x$

$l≔\mathrm{LinkedList}:-\mathrm{Prepend}\left(l\,y\right)$

$l≔y,x$

$l≔\mathrm{LinkedList}:-\mathrm{Prepend}\left(l\,z\right)$

$l≔z,y,x$