Catalytic Cracking of Ethane

All Products Maple MapleSim

Home : Support : Online Help : Applications and Example Worksheets : Science and Engineering : Catalytic Cracking of Ethane

Catalytic Cracking of Ethane

Introduction

Ethylene and hydrogen are generated by a steam cracker using ethane as a feedstock.

C₂H₆ (g) ⇌ C₂H₄ (g) + H₂ (g)

The feed is 4 mol of H₂O to 1 mol of ethane, with the cracker operating at 1.01 bar and 1000 K. The products contain CH₄, C₂H₄, C₂H₂, CO₂, CO, O₂, H₂, H₂O, and C₂H₆ in the molar amounts n₁ to n₉.

	Species	In Feed	In Product
1	CH₄		n₁
2	C₂H₄		n₂
3	C₂H₂		n₃
4	CO₂		n₄
5	CO		n₅
6	O₂		n₆
7	H₂		n₇
8	H₂O	4	n₈
9	C₂H₆	1	n₉

This application calculates the composition of the reaction products by

•	calculating the Gibbs energy of formation of the individual species in the products, employing data from the ThermophysicalData:-Chemicals package

•	constructing a function that describes Gibbs Energy of the products as a function of product composition

•	and minimizing the Gibbs Energy of the products, subject to constraints.

>	restart: with(ThermophysicalData:-Chemicals): with(Optimization):

>	temp := 1000 * Unit(K): R := 8.314 * Unit(J/mol/K):

Physical Properties

Enthalpies

h_CH4 := Property("Hmolar", "CH4",            temperature = temp):
h_C    := Property("Hmolar", "C(gr)",          temperature = temp):
h_H2   := Property("Hmolar", "H2",             temperature = temp):
h_H2O := Property("Hmolar", "H2O",            temperature = temp):
h_O2   := Property("Hmolar", "O2",             temperature = temp):
h_CO   := Property("Hmolar", "CO",             temperature = temp):
h_CO2 := Property("Hmolar", "CO2",            temperature = temp):
h_C2H4 := Property("Hmolar", "C2H4",           temperature = temp):
h_C2H2 := Property("Hmolar", "C2H2,acetylene", temperature = temp):
h_C2H6 := Property("Hmolar", "C2H6",           temperature = temp):

Entropies

s_CH4 := Property("Smolar", "CH4",            temperature = temp):
s_C    := Property("Smolar", "C(gr)",          temperature = temp):
s_H2   := Property("Smolar", "H2",             temperature = temp):
s_H2O := Property("Smolar", "H2O",            temperature = temp):
s_O2   := Property("Smolar", "O2",             temperature = temp):
s_CO   := Property("Smolar", "CO",             temperature = temp):
s_C    := Property("Smolar", "C(gr)",          temperature = temp):
s_CO2 := Property("Smolar", "CO2",            temperature = temp):
s_C2H4 := Property("Smolar", "C2H4",           temperature = temp):
s_C2H2 := Property("Smolar", "C2H2,acetylene", temperature = temp):
s_C2H6 := Property("Smolar", "C2H6",           temperature = temp):

Gibbs energy of formation

CH₄

C (gr) + 2 H₂ (g) → CH₄ (g)

Enthalpy change

>	DeltaH := 1Unit(mol)h_CH4 - (1Unit(mol)h_C + 2Unit(mol)h_H2)

$- 89.07 ⟦kJ⟧$

(3.1.1)

Entropy change

>	DeltaS := 1Unit(mol)s_CH4 - (1Unit(mol)s_C + 2Unit(mol)s_H2)

$- 108.55 ⟦\frac{J}{K}⟧$

(3.1.2)

Gibbs energy of formation

>	DeltaG_CH4 := DeltaH - DeltaS*temp

$19.49 ⟦kJ⟧$

(3.1.3)

H₂O

H₂ (g) + 0.5 O₂ (g) → H₂O (l)

Enthalpy Change

>	DeltaH := 1Unit(mol)h_H2O - (1Unit(mol)h_H2 + 0.5Unit(mol)h_O2)

$- 247.86 ⟦kJ⟧$

(3.2.1)

Entropy change

>	DeltaS := 1Unit(mol)s_H2O - (1Unit(mol)s_H2 + 1/2Unit(mol)s_O2)

$- 55.27 ⟦\frac{J}{K}⟧$

(3.2.2)

Gibbs energy of formation

>	DeltaG_H2O := DeltaH - DeltaS*temp

$- 192.58 ⟦kJ⟧$

(3.2.3)

C (gr) + 0.5 O₂ (g) → CO (g)

Enthalpy change

>	DeltaH := 1Unit(mol)h_CO - (1Unit(mol)h_C + 0.5Unit(mol)h_O2)

$- 112.00 ⟦kJ⟧$

(3.3.1)

Entropy change

>	DeltaS := 1Unit(mol)s_CO - (1Unit(mol)s_C + 0.5Unit(mol)s_O2)

$88.29 ⟦\frac{J}{K}⟧$

(3.3.2)

Gibbs energy of formation

>	DeltaG_CO := DeltaH - DeltaS*temp

$- 200.29 ⟦kJ⟧$

(3.3.3)

CO₂

C (gr) + O₂ (g) → CO₂ (g)

Enthalpy change

>	DeltaH := 1Unit(mol)h_CO2 - (1Unit(mol)h_C + 1Unit(mol)h_O2)

$- 394.61 ⟦kJ⟧$

(3.4.1)

Entropy change

>	DeltaS := 1Unit(mol)s_CO2 - (1Unit(mol)s_C + 1Unit(mol)s_O2)

$1.26 ⟦\frac{J}{K}⟧$

(3.4.2)

Gibbs Energy of Formation

>	DeltaG_CO2 := DeltaH - DeltaS*temp

$- 395.87 ⟦kJ⟧$

(3.4.3)

C₂H₄

2 C (gr) + 2 H₂ (g) → C₂H₄ (g)

Enthalpy change

>	DeltaH := Unit(mol)h_C2H4 - (2Unit(mol)h_C + 2Unit(mol)*h_H2)

$38.22 ⟦kJ⟧$

(3.5.1)

Entropy change

>	DeltaS := Unit(mol)s_C2H4 - (2Unit(mol)s_C + 2Unit(mol)*s_H2)

$- 80.93 ⟦\frac{J}{K}⟧$

(3.5.2)

Gibbs energy of formation

>	DeltaG_C2H4 := DeltaH - DeltaS*temp

$119.15 ⟦kJ⟧$

(3.5.3)

C₂H₂

2 C (gr) + H₂ (g) → C₂H₂ (g)

Enthalpy change

>	DeltaH := Unit(mol)h_C2H2 - (2Unit(mol)h_C + 1Unit(mol)*h_H2)

$224.98 ⟦kJ⟧$

(3.6.1)

Entropy change

>	DeltaS := Unit(mol)s_C2H2 - (2Unit(mol)s_C + 1Unit(mol)*s_H2)

$53.80 ⟦\frac{J}{K}⟧$

(3.6.2)

Gibbs energy of formation

>	DeltaG_C2H2 := DeltaH - DeltaS*temp

$171.18 ⟦kJ⟧$

(3.6.3)

C₂H₆

2 C (gr) + 3 H₂ (g) → C₂H₆ (g)

Enthalpy change

>	DeltaH := Unit(mol)h_C2H6 - (2Unit(mol)h_C + 3Unit(mol)*h_H2)

$- 105.04 ⟦kJ⟧$

(3.7.1)

Entropy change

>	DeltaS := Unit(mol)s_C2H6 - (2Unit(mol)s_C + 3Unit(mol)*s_H2)

$- 215.88 ⟦\frac{J}{K}⟧$

(3.7.2)

Gibbs energy of formation

>	DeltaG_C2H6 := DeltaH - DeltaS*temp

$110.83 ⟦kJ⟧$

(3.7.3)

H₂

>	DeltaG_H2:= 0:

O₂

>	DeltaG_O2:= 0:

Constraints

A mole balance on the carbon, hydrogen and oxygen gives these constraints

Carbon	n₁ + 2 n₂ + 2 n₃ + n₄ + n₅ + 2 n₉ = 2
Hydrogen	4 n₁ + 4 n₂ + 2 n₃ + 2 n₇ + 2 n₈ + 6 n₉ = 14
Oxygen	2 n₄ + n₅ + 2 n₆ + n₈ = 4

>	cons := n1 + 2n2 + 2n3 + n4 + n5 + 2n9 = 2 Unit(mol) ,4n1 + 4n2 + 2n3 + 2n7 + 2n8 + 6n9 = 14 * Unit(mol) ,2n4 + n5 + 2n6 + n8 = 4 * Unit(mol):

Gibbs Energy of the Products

Collect the Gibbs Energy of all species in a list

>	DeltaG := [DeltaG_CH4, DeltaG_C2H4, DeltaG_C2H2, DeltaG_CO2, DeltaG_CO, DeltaG_O2, DeltaG_H2, DeltaG_H2O, DeltaG_C2H6] /~ Unit(mol):

Total Gibbs Energy of the products

>	Gt := n -> local i; add(n[i] * DeltaG[i], i=1..9) + R * temp * add(n[i] * ln(((n[i] + 1e-10*Unit(mol))/ add(n[i], i=1..9))), i=1..9):

Optimization

>	Digits := 20:

composition := Minimize(Gt([n1, n2, n3, n4, n5, n6, n7, n8, n9]), {cons}, initialpoint = [n1 = 1 * Unit(mol), n2 = 1 * Unit(mol), n3 = 1 * Unit(mol), n4 = 1 * Unit(mol), n5 = 1 * Unit(mol), n6 = 1 * Unit(mol), n7 = 1 * Unit(mol), n8 = 1 * Unit(mol), n9 = 1 * Unit(mol)], assume = nonnegative, iterationlimit = 300):

Hence the product composition is

>	composition[2]

$[n1 = 6.75 \times 10^{- 2} ⟦mol⟧, n2 = 9.13 \times 10^{- 8} ⟦mol⟧, n3 = 2.77 \times 10^{- 10} ⟦mol⟧, n4 = 5.57 \times 10^{- 1} ⟦mol⟧, n5 = 1.38 \times 10^{0} ⟦mol⟧, n6 = 0.00 \times 10^{0}, n7 = 5.35 \times 10^{0} ⟦mol⟧, n8 = 1.51 \times 10^{0} ⟦mol⟧, n9 = 1.50 \times 10^{- 7} ⟦mol⟧]$

(6.1)

Download Help Document

Maple

Maple 附加模块

Math Success Platform

提高存留率

Maple Flow

MapleSim

项目服务

Maple T.A. and Möbius

教育

行业

汽车与航空航天

机器人

机器设计和工业自动化

其他

应用领域

产品价格

购买

院系/全校正版授权

Maplesoft精英维护升级计划

支持

产品培训

产品在线帮助

研讨会与活动

出版

资源中心

示例和应用

社区

关于 Maplesoft

媒体中心

用户社区

联系我们

Online Help

All Products Maple MapleSim

Maple

数学软件

Maple 附加模块

Math Success Platform

提高存留率

Maple Flow

Engineering calculations & documentation

MapleSim

多学科系统级建模仿真

项目服务

Maple T.A. and Möbius

教育

行业

汽车与航空航天

机器人

机器设计和工业自动化

其他

应用领域

产品价格

购买

院系/全校正版授权

Maplesoft精英维护升级计划

支持

产品培训

产品在线帮助

研讨会与活动

出版

资源中心

示例和应用

社区

关于 Maplesoft

媒体中心

用户社区

联系我们

Online Help

All Products Maple MapleSim