Object ルーチンは、与えられたオブジェクトをコピーして新規の object を作成します。

新規オブジェクトの宣言に関する詳細は、Object,create を参照してください。Maple におけるオブジェクトの概要については、object を参照してください。

与えられたオブジェクトが ModuleCopy ルーチンを実装していない場合、Object はオブジェクト obj の static でないメンバーの値を新規オブジェクトにコピーします。

オブジェクトが ModuleCopy ルーチンを実装している場合は、Object を呼び出すと ModuleCopy ルーチンを実行します。追加パラメータ (arg1, ...) も ModuleCopy ルーチンに渡されます。

ModuleCopy を実行する Object を呼び出す ModuleApply ルーチンを実装し、オブジェクトにプロトタイプオブジェクトを適用します。

Object コマンドは Maple 16 で導入されました。

Maple 16 における変更点についての詳細は、Maple 16 の新機能 を参照してください。

module Obj()
   option object;
   local data := 0;
   export getData::static := proc( self::Obj )
       self:-data;
   end;
   export setData::static := proc( self::Obj, d )
       self:-data := d;
   end;
end:

getData( Obj );

newObj1 := Object( Obj );

getData( newObj1 );

setData( newObj1, 10 );

newObj2 := Object( newObj1 );

getData( newObj2 );

module Obj2()
   option object;
   local data := 0;
   export getData::static := proc( self::Obj2 )
       self:-data;
   end;
   export ModuleCopy::static := proc( self::Obj2, proto::Obj2, d, $ )
       if ( _npassed = 2 ) then
           self:-data := proto:-data;
       else
           self:-data := d;
       end;
   end;
end:

getData( Obj2 );

newObj1 := Object( Obj2 );

getData( newObj1 );

newObj2 := Object( Obj2, 10 );

getData( newObj2 );

module Obj3()
   option object;
   local data := 0;
   export getData::static := proc( self::Obj3 )
       self:-data;
   end;
   export ModuleApply::static := proc( )
       Object( Obj3, _passed );
   end;
   export ModuleCopy::static := proc( self::Obj3, proto::Obj3, d, $ )
       if ( _npassed = 2 ) then
           self:-data := proto:-data;
       else
           self:-data := d;
       end;
   end;
end:

newObj1 := Obj3( );

getData( newObj1 );

newObj2 := Obj3( 10 );

getData( newObj2 );