モジュール定義における export 句は、そのモジュールが実装された後でありさえすればクライアントからアクセス可能な、１個以上の変数を「宣言」するために用います。変数名は、そのモジュール外部ではメンバー選択演算子 :- を使ってアクセスします。このような変数をそのモジュールの「エクスポート変数」と呼びます。式 e1, e2, ... のそれぞれは、記号、あるいは、sysymbol::type の形の式のいずれかである必要があります。 後者の場合、宣言は、エクスポートに割り当てられた値の型にも影響します。  

モジュールのエクスポート変数に関して最も重要なことは、そのモジュールに対しては局所変数として機能するということです。エクスポート変数名の通用する範囲は、そのモジュールの局所変数のそれと完全に一致します。大きな違いは、そのモジュールが実装された後であっても、エクスポート変数を「見る」ことができるという点にあります。

モジュールのエクスポート変数の評価規則は、モジュールの局所変数のそれと同じであり、手続きの局所変数の評価規則とも同じです（詳細については eval を参照して下さい）。

モジュールのエクスポート変数の集合は固定されたものであり、そのモジュール定義が評価されるのと同時にセットされます。いったん実装されたモジュールのエクスポート変数の集合は変更不可能です。

エクスポート変数名は明示的に宣言する必要が有ります。暗黙の通用規則によって、変数名がエクスポート変数として解釈されることは無いのです。

モジュール m のエクスポート変数 s に、 m の中にあるモジュールを割り当てることができます（すなわち、s は m の部分モジュールなのです）。部分モジュール s のエクスポート変数は、m の部分モジュール s を m:-s により指定した後に、s の適当なエクスポート変数 e を m:-s:-e として選択することにより、アクセス可能になります。

m:= module() export a, b, c; option package; end module;

m:-a;

evalb( a = m:-a ); # not the same name

m:-a := 5;

m:-a;

a;

with( m );

a;

m := module()
        export s, p;
        s := module()
                export e;
                e := 2
        end module;
        p := proc()
                s:-e
        end proc
end module:
m:-s:-e;

m:-p();

m := module()
        export p;
        local s;
        s := module()
                export e;
                e := 2
        end module;
        p := proc()
                s:-e
        end proc
end module:
m:-s:-e;

Error, module does not export `s`

m:-p(); # still okay

m := module()
        export p;
        local s;
        s := module()
                local e;
                e := 2
        end module;
        p := proc()
                s:-e # error, not an export of s
        end proc
end module:
m:-s:-e;

Error, module does not export `s`

m:-p();

Error, (in p) module does not export `e`